用汇编语言用汇编语言编写从键盘上输入N个学生的成绩，然后按成绩降序输出显示各学生的成绩。
用汇编来写程序，还有输入输出，这个跟操作系统有关，这是何苦来？
; 本程序通过编译，运行正确
Code Segment
Assume CS:Code,DS:Code
CR equ 000DH
LF equ 000AH
KBBack equ 0008H
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出一个字符
; 入口：dl=要显示的字符
Output_Chr proc Near
push ax
mov ah,02h
int 21h
pop ax
ret
Output_Chr endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出回车换行
Output_CTLF proc Near
push ax
push dx
mov ah,02h
mov dl,0dh
int 21h
mov dl,0ah
int 21h
pop dx
pop ax
ret
Output_CTLF endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：取光标位置
; 入口：无
; 出口：DH=行号，DL=列号
GetCursor Proc Near
PUSH AX
PUSH BX
PUSH CX
XOR BX,BX
MOV AH,3
INT 10H
MOV Cursor_Row,DH
MOV Cursor_Col,DL
POP CX
POP BX
POP AX
RET
Cursor_Row DB ?
Cursor_Col DB ?
GetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：置光标位置
; 入口：Cursor_Row=行坐标; Cursor_Col: 列坐标)
SetCursor Proc Near
PUSH DX
PUSH CX
PUSH BX
PUSH AX
MOV DH,Cursor_Row
MOV DL,Cursor_Col
XOR BX,BX
MOV AH,2
INT 10H
POP AX
POP BX
POP CX
POP DX
RET
SetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：键盘输入一个指定位数的十进制数字，将其转换成二进制数并保存在指定的内存单元。
; 入口：@@Digits=数字位数；di=保存输入的数字首地址
; @@Type_Data=保存的数据类型，B=字节类型，W=字类型。
; 出口：转换后的二进制数保存在di所指的单元
Input_Digit Proc Near
push dx
push cx
push bx
push di
lea di,@@Save_Tmp
push di
cld
mov cl,@@Digits
xor ch,ch
push cx
@@Input: call GetCursor ;取光标位置
mov ah,1 ;从键盘接受一个字符
int 21h
cmp al,CR ;若键入的是回车，已经键入的数字不足N位
jz @@ASC_Dec ;转去处理已经键入的数字
cmp al,KBBack
jz @@KB_Back ;若是回空键，重新输入
cmp al,'0'
jb @@KBBack ;若低于数字'0'，重新输入
cmp al,'9'
ja @@KBBack ;若低于数字'9'，重新输入
jmp @@Save_Dig
@@KB_Back: dec Cursor_Col
inc cx
dec di
@@KBBack: call SetCursor ;置光标位置
jmp @@Input
@@Save_Dig: and al,0fh ;转换成二进制数
stosb ;保存
loop @@Input ;接受下一个数字
@@ASC_Dec: mov ax,cx
pop cx
pop si
sub cx,ax ;实际输入的数字位数
xor bp,bp
xor dx,dx
xor ax,ax
jcxz @@Retturn ;若是直接回车，没有输入任何数字，按输入'0'处理
dec cx ;实际输入的数字位数减1，准备把输入的这一串数字转换成二进制数
jcxz @@One_Digit ;若输入的数字只有一位，转去直接保存这个二进制数
mov bx,10
@@Mul_Ten: lodsb
cbw
add ax,bp
mul bx
mov bp,ax
loop @@Mul_Ten
@@One_Digit:lodsb
cbw
add ax,bp
@@Save_Ret: pop di
cmp @@Type_Data,'B' ;字节类型？
jz $+5
stosw
jmp $+3
stosb
pop bx
pop cx
pop dx
clc
ret
@@Retturn: pop di
pop bx
pop cx
pop dx
stc
ret
@@Digits db ? ;十进制数字位数
@@Type_Data db 'B' ;保存的数据类型。B=字节类型，W=字类型
@@Save_Tmp db 16 dup(?)
Input_Digit EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Prompt_Str db 'Please input a score(0-3digits): $' ;提示输入一个分数
Score db ? ;存放分数
Press_Key db 13,10,13,10,'Press any key to exit...$'
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 输入成绩
mov @@Digits,3 ;十进制数字位数
mov @@Type_Data,'B' ;保存的数据类型。B=字节类型，W=字类型
Input_Score:Output prompt_Str ;提示输入分数
lea di,Score ;成绩存放地址
call Input_Digit ;输入分数
jc @@Any_Key ;若是直接回车，没有输入任何数字，则结束程序
mov dl,10 ; 用于除10
mov al,Score ; 提取分数
xor ah,ah
div dl ; 除10
cmp al,5 ; >5，及格
ja $+4
mov al,5 ; <=5，不及格
sub al,5 ; 减5
mov dl,'F'
test al,0ffh
jz $+8
cmp al,5
jz $+4
inc al
add Cursor_Col,6
call SetCursor
sub dl,al
call Output_Chr ;显示一个字符
call Output_CTLF ;输出一个回车、换行
jmp Input_Score
@@Any_Key: Output Press_Key
mov ah,1
int 21h
Exit_Proc: mov ah,4ch ;结束程序
int 21h
Code ENDS
END Start ;编译到此结束
学生成绩输出时是先输出成绩，再输出其序号。
CODE SEGMENT
ASSUME CS:CODE
ORG 100H
START: PUSH CS
POP DS
PUSH CS
POP ES
CALL INPUTNUM
MOV AH,2
MOV DL,13
INT 21H
MOV DL,10
INT 21H
LEA SI,@ARRAY
LEA BP,@XUHAO
MOV CX,@NUM
CALL SORTWORD
LEA SI,@ARRAY
LEA BX,@XUHAO
MOV CX,@NUM
CLD
@1:
LODSW
CALL DSPAXS
MOV AX,[BX]
CALL DSPAXS
INC BX
INC BX
MOV AH,2
MOV DL,13
INT 21H
MOV DL,10
INT 21H
LOOP @1
MOV AH,4CH
INT 21H
;===============================================
; 键盘输入数值数组子程序（数组名为@array，元素个数存放在@num中）
; 可以是负数
; 采用字符串缓冲方式输入
INPUTNUM PROC NEAR
PUSH AX
PUSH BX
PUSH CX
PUSH DX
PUSH SI
PUSH DI
PUSHF
; 对数组@array清零
MOV CX,100
MOV AX,0
LEA DI,@ARRAY
CLD
REP STOSW
;;;;;;;;;;;;;;;;;;;;;;;;;;;; 初始化序号数组
MOV CX,100
MOV AX,1
LEA DI,@XUHAO
@WXUHAO:
STOSW
INC AX
LOOP @WXUHAO
;;;;;;;;;;;;;;;;;;;;;;;;;;;;
MOV WORD PTR @NUM,0
; 输入的数据以一个空格分隔，以回车符结束输入
LEA DX,@STRA
MOV AH,10
INT 21H
MOV CL,@STRN
MOV CH,0
MOV WORD PTR @STRM,CX
LEA SI,@STR
CLD
LEA DI,@ARRAY ;将数组第一个元素的有效地址置入DI
MOV WORD PTR @NUM,0
@STIN:
MOV AX,0
PUSH AX
MOV BYTE PTR @SIGNN,0
@AGAIN1:
CMP WORD PTR @STRM,0
JE @LINE0
LODSB
DEC WORD PTR @STRM
CMP AL,' '
JE @LINE0
CMP AL,'-'
JNE @INPUT1
MOV BYTE PTR @SIGNN,1
JMP @AGAIN1
@INPUT1:
SUB AL,30H
MOV AH,0
MOV BX,AX
POP AX
MOV CL,10
MOV CH,0
MUL CX
ADD AX,BX
PUSH AX
JMP @AGAIN1
@LINE0:
POP AX
CMP BYTE PTR @SIGNN,1
JNE @INPUT2
NEG AX
@INPUT2:
MOV WORD PTR[DI],AX
INC WORD PTR @NUM
CMP WORD PTR @STRM,0
JE @STINEND
INC DI
INC DI
JMP @STIN
@STINEND:
POPF
POP DI
POP SI
POP DX
POP CX
POP BX
POP AX
RET
@STRA DB 255
@STRN DB ?
@STR DB 255 DUP(?)
@STRM DW 0
@ARRAY DW 100 DUP(0)
@NUM DW 0
@CHAR DB ?
@SIGNN DB 0
@XUHAO DW 100 DUP(0)
INPUTNUM ENDP
;===============================
; 字数组排序（有符号数冒泡排序）
SORTWORD PROC NEAR
; 数组长度置入cx，字数组首地址置入 si ，序号数组首地址 置入 bp
PUSH AX
PUSH BX
PUSH CX
PUSH DX
PUSH SI
PUSH DI
PUSH BP
PUSHF
PUSH CX
POP DX
DEC DX
@SORTWL1:
MOV CX,DX
MOV DI,SI
MOV BX,BP
@SORTWL2:
MOV AX,[DI+2]
CMP AX,[DI]
JL @SORTWNEXT ; 从大到小（无符号换成 JB）
XCHG AX,[DI]
MOV [DI+2],AX
;====================
MOV AX,[BX+2]
XCHG AX,[BX]
MOV [BX+2],AX
;====================
@SORTWNEXT:
INC DI
INC DI
INC BX
INC BX
LOOP @SORTWL2
DEC DX
JNZ @SORTWL1
POPF
POP BP
POP DI
POP SI
POP DX
POP CX
POP BX
POP AX
RET
SORTWORD ENDP
;=================================
DSPAXS PROC NEAR
PUSH AX
TEST AX,8000H
JNS @DSPAXS1
PUSH AX
PUSH DX
MOV AH,2
MOV DL,'-'
INT 21H
POP DX
POP AX
NEG AX
@DSPAXS1:
CALL DSPAX
POP AX
RET
DSPAXS ENDP
;===============================
DSPAX PROC NEAR
PUSH AX
PUSH BX
PUSH CX
PUSH DX
PUSHF
XOR CX,CX
MOV BX,10
@DSPAX1:
XOR DX,DX
DIV BX
INC CX
OR DX,30H
PUSH DX
CMP AX,0
JNE @DSPAX1
MOV AH,2
@DISPAX2:
POP DX
INT 21H
LOOP @DISPAX2
MOV DL,32
INT 21H
POPF
POP DX
POP CX
POP BX
POP AX
RET
DSPAX ENDP
;==================================
CODE ENDS
END START
用汇编语言编译一个程序\\从键盘输入一个字符串将其每个字符的ASCII码...
end main 上面的程序是：从键盘输入1~5之间的一个数，在屏幕上显示one…five。虽然不一样，但要求差不多，希望对你有帮助！
用汇编语言编程:从键盘输入一行字符,统计字母、空格、数字、其他字符的...
;从键盘输入一行字符，统计字母、空格、数字、其他字符的个数，并显示 ;用80x86汇编语言编程如下：;--- DATA SEGMENT PARS DB 100 ;准备接收100个字符.NNN DB ? ;用于存放实际输入的个数.III DB 100 DUP(?) ;100字节的空间.N_N DB ?S_N DB ?C_N DB ?O_N ...
用汇编语言编写一个代码:从键盘上输入一个字符;把其中的大写字母改为...
从键盘输入的任何字符的字符串，一个字母大写输出。数据段 MSG1 DB 13，10，'请输入一个STR：MSG2 DB 13，10，'上的STR是：$'> I1_L DB 100 I1_N DB？ I1_B DB 100 DUP（？）数据 代码段 假设CS：CODE，DS：DATA START：MOV结束AX，DATA MOV DS，AX LEA DX，MSG1 MOV AH，9 ...
用汇编语言 设计一个 从键盘输入十个数 ,求每个数所占 百分比的 程序...
很多东西网上有现成的参考资料,建议多用用搜索引QING...
用汇编语言写:从键盘输入一个十进制数(100以内),将其转变为二进制数并...
lea dx,para mov ah,9 int 21h ENDM data segment buffer db 2,0,2 dup(?)TEN db '请输一个100之内的两位数:$'HEX db '16进制:$'BIN db ' 2进制:$'CRLF db 0dh,0ah,24h data ends code segment assume cs:code, ds:data start: mov ax，data mov ds，ax mL1: print ...
急~~用汇编语言编写出从键盘输入10个字符然后相反的顺序将字符输出_百 ...
mov ah,0ah ;从键盘接受一串字符 int 21h CALL Enter_CTLF ;输出一个回车、换行 CALL Enter_CTLF ;输出一个回车、换行 cld lea si,Buffer[1] ;实际输入的字符个数地址 mov cl,[si] ;读入实际输入的字符个数 test cl,0ffh jz Exit_Proc ;直接回车，没有输入任何字符，结束程序，...
用汇编语言编写:从键盘输入一个十进制数(100以内),将其转变为二进制数...
NUMBER DB 3 DB ?db 3 DUP(0)DSEG ENDS CSEG SEGMENT assume cs:CSEG, ds:DSEG MAIN PROC FAR mov ax, dseg mov ds, ax lea dx,INPUT mov ah,9 int 21h lea dx,NUMBER mov ah,0ah int 21h lea dx,OUTPUT mov ah,9 int 21h mov bl,NUMBER+2 sub bl,30h cmp NUMBER+1,1 jz...
[汇编语言]由键盘输入任意字符串 然后显示出来
code segment assume cs:code,ds:data main proc far mov ax,data mov ds,ax lea dx,keyboard mov ah,0ah;输入字符串 int 21h lea di,keyboard mov cl,[di+1];取出实际输入字符的个数 mov ch,0 add di,2;指向第一个字符 next:mov dl,[di]mov ah,2;循环输出字符 int 21h inc di l...
用汇编语言用汇编语言编写从键盘上输入N个学生的成绩,然后按成绩降序输 ...
学生成绩输出时是先输出成绩，再输出其序号。 CODE SEGMENT ASSUME CS:CODE ORG 100H START: PUSH CS POP DS PUSH CS POP ES CALL INPUTNUM MOV AH,2 MOV DL,13 INT 21H...
汇编语言,键盘任意输入10个1位十进制数,将它们累加求和,把和放在Sum...
汇编语言编程中，处理键盘输入和数值处理是一个常见的任务。假设我们需要编写一段程序，能够接收用户通过键盘输入的10个1位十进制数，并将这些数累加求和。程序将把结果存储在一个名为Sum的单元中，并以十进制形式显示。下面是一个简单的汇编语言示例，展示如何实现这一功能。首先，程序需要初始化环境，...