单片机，我有一个秒表00.0计时的汇编语言 程序 谁能帮我解释下这些程序 跪求
程序写的可以，但是在硬软件资源使用上不科学。1.位寻址寄存器20H~2FH应专做为寻址用，平时的字节寄存器应从30H开始不较好。2.P3口各个引脚都有第二功能，能不用尽量不用。比如这次的电路：数码管a~g用P2口，位选用P1.0~P1.1，按键用P1.2~P1.4，完全够用。3.汇编编程要适当添加注释，提高程序可读性！
我是在你的程序基础上改的，用注释标注了！
;================================================================
;功能：本程序实现P0口的对数码管动态显示秒表的分、秒、1/100秒；
; 计时程序由中断服务程序实现，采用定时计数器T0工作方式1；
; P2口实现对数码管的片选功能
;================================================================
;==========================初始化================================
SHUCHU EQU P2 ;定义P0口为输出口
PIANXUAN EQU P1 ;定义P2口为片选口
MIAO EQU 30H
FEN EQU 31H
MIAO0 EQU 32H
SHUZI EQU 33H
C_0 BIT 20H.0
;======================系统程序开始==============================
ORG 00H
LJMP START
ORG 03H
LJMP ON_OFF
ORG 0BH
LJMP T0_1
ORG 13H
LJMP RESET
ORG 30H
START:
CALL INIT
SETB C_0
MOV MIAO,#00
MOV MIAO0,#00
MOV FEN,#00
MOV DPTR,#TAB
MOV R2,#5
MAIN:
JNB C_0,$
CLR C_0
LL: CALL DISPLAY
CALL SHIJIAN
JMP MAIN
;========================时间子程序=============================
;输入:"30H、31H、32H"
;输出:无
;实现的功能：分、秒、百分之秒的计算。
;===============================================================
SHIJIAN:
DJNZ R2,TIAOCHU
MOV R2,#5
INC MIAO0
MOV R3,MIAO0
CJNE R3,#100,TIAOCHU
MOV MIAO0,#00
INC MIAO
MOV R3,MIAO
CJNE R3,#60,TIAOCHU
MOV MIAO,#00
INC FEN
MOV R3,FEN
CJNE R3,#60,TIAOCHU
MOV FEN,#00
TIAOCHU:RET
;========================显示子程序=============================
;输入:"A"
;输出:"P2口"
;实现的功能：显示秒、分、百分之妙
;===============================================================
DISPLAY:MOV SHUZI,MIAO0
CALL JISUAN
MOVC A,@A+DPTR
MOV SHUCHU,A ;显示十位
MOV PIANXUAN,#10H ;片选
CALL DELAY
MOV PIANXUAN,#00H
MOV A,B
MOVC A,@A+DPTR
MOV SHUCHU,A ;显示个位
MOV PIANXUAN,#20H ;片选
CALL DELAY ;延时
MOV PIANXUAN,#00H
MOV SHUZI,MIAO
CALL JISUAN
MOVC A,@A+DPTR
MOV SHUCHU,A ;显示十位
MOV PIANXUAN,#04H ;片选
CALL DELAY
MOV PIANXUAN,#00H
MOV A,B
MOVC A,@A+DPTR
MOV SHUCHU,A ;显示个位
MOV PIANXUAN,#08H ;片选
CALL DELAY ;延时
MOV PIANXUAN,#00H
MOV SHUZI,FEN
CALL JISUAN
MOVC A,@A+DPTR
MOV SHUCHU,A ;显示十位
MOV PIANXUAN,#01H ;片选
CALL DELAY
MOV PIANXUAN,#00H
MOV A,B
MOVC A,@A+DPTR
MOV SHUCHU,A ;显示个位
MOV PIANXUAN,#02H ;片选
CALL DELAY ;延时
MOV PIANXUAN,#00H
RET
;========================计算子程序=============================
;输入:30H
;输出:"A和B"
;实现的功能：把33H中的数据十位和个位分离出来
;===============================================================
JISUAN:MOV A,SHUZI ;数据放在A中
MOV B,#10 ;除数放在B中
DIV AB ;商放在A中，余数放在B中
RET
;====================复位中断服务程序============================
;输入；无
;输出: 无
;实现的功能：把30H、31H、32H中的数据清零。
;================================================================
RESET:PUSH ACC
MOV 30H,#00H
MOV 3H,#00H
MOV 32H,#00H
CALL DELAY
POP ACC
RETI
;====================启停中断服务程序============================
;输入；无
;输出: 无
;实现的功能：关闭定时器
;================================================================
ON_OFF:CPL TR0
CALL DELAY
RETI
;====================定时中断0服务子程序========================
;输入:无
;输出:无
;实现的功能：实现定时20MS，影响标中断志位C_0
;===============================================================
T0_1:MOV TL0,50H ;设置定时初值
MOV TH0,51H
SETB C_0 ;定时标志位清0
RETI
;========================中断设置子程序=========================
;输入:无
;输出:无
;实现的功能：初始化设置定时器，设置初值，开中断0、中断1，定时器0.
;===============================================================
INIT:MOV TMOD,#01H ;定时器0工作方式1
MOV DPTR,#65536-20000
MOV 50H,DPL
MOV 51H,DPH
MOV TL0,50H ;设置定时初值
MOV TH0,51H
MOV IE,#87H ;开定时器中断0
MOV TCON,#15H
RET
;======================延时程序==================================
;输入；无
;输出: 无
;实现的功能：延时一段时间
;================================================================
DELAY:MOV R6,#80
L7:MOV R5,#60
L8:DJNZ R5,$
DJNZ R6,L7
RET
;======================共阳查表数据==============================
TAB:DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
;===========================结束=================================
END
数码管显示：R4，R5，R6
按键K1，开始...
但没有看到K2的处理程序,
没写完吧？
参考：
http://hi.baidu.com/do_sermon/item/639cf3015fd5d1c990571899
c语言的 行吗
汇编 也可以
单片机,我有一个秒表00.0计时的汇编语言 程序 谁能帮我解释下这些程序...
50MS T0 中断 倒计时R4，R5，R6!数码管显示：R4，R5，R6 按键K1，开始...但没有看到K2的处理程序,没写完吧？
NBA比赛过程中,计时如何做到那么准的啊?
每节比赛到最后2分钟，可以看回放。尤其到了第四节最后的2分钟，有争议的话，裁判全都会看现场回放，一般回表是可以精确到秒的，这是目前争取把失误降至最低的最好办法。
nba比赛时为什么有时再发球时不停计时器?
h. 如果防守球员致球出界或导致球从蓝筐下方进入篮筐，24秒计时器停止计时，球权判给进攻球队。进攻球队只有在24秒计时器时限未到时方能出手投篮。如果24秒计时器显示为0，即使蜂鸣器没有响起，依然判为24秒违例。i. 任一节比赛，若该节比赛剩余时间为24秒或不足24秒，球权转换时，24秒计时器不执...
nba比赛时为什么有时再发球时不停计时器
f 比赛计时器和计分板应在一节比赛的比赛时间结束时一起自动地鸣响报警器。如果报警器或者蜂鸣器没能鸣响，或者鸣响后没有被听到，官方计时员应立刻使用任何其他方式提醒裁判。g 在死球状态下，如果计时器显示为00.0秒，该节比赛将被认定已经结束，尽管此时警报器可能尚未鸣响。